Repository navigation
Expand file tree
/
Copy pathflake.nix
More file actions
211 lines (189 loc) · 5.76 KB
/
Copy pathflake.nix
File metadata and controls
211 lines (189 loc) · 5.76 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
{
inputs = {
crane = {
url = "github:ipetkov/crane";
inputs.nixpkgs.follows = "nixpkgs";
inputs.flake-compat.follows = "";
inputs.rust-overlay.follows = "";
};
fenix = {
url = "github:nix-community/fenix";
inputs.nixpkgs.follows = "nixpkgs";
inputs.rust-analyzer-src.follows = "";
};
flake-parts = {
url = "github:hercules-ci/flake-parts";
inputs.nixpkgs-lib.follows = "nixpkgs";
};
nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
};
outputs = inputs@{ crane, flake-parts, ... }:
flake-parts.lib.mkFlake { inherit inputs; } {
systems = [
"aarch64-darwin"
"aarch64-linux"
"x86_64-darwin"
"x86_64-linux"
];
perSystem = { inputs', lib, pkgs, self', system, ... }:
let
inherit (builtins)
attrValues
getAttr
listToAttrs
readDir
;
inherit (lib)
concatMapAttrs
flip
getExe
hasSuffix
importTOML
licenses
maintainers
nameValuePair
optionalAttrs
optionals
pipe
sourceByRegex
;
inherit (crane.lib.${system}.overrideToolchain inputs'.fenix.packages.default.toolchain)
buildDepsOnly
buildPackage
cargoClippy
cargoFmt
cargoNextest
;
inherit (pkgs)
bzip2
callPackage
curl
darwin
installShellFiles
libgit2
libiconv
mkShell
nix
nixpkgs-fmt
nurl
openssl
pkg-config
spdx-license-list-data
stdenv
zlib
zstd
;
src = sourceByRegex ./. [
"(license-store-cache|src)(/.*)?"
''Cargo\.(toml|lock)''
''build\.rs''
''rustfmt\.toml''
];
get-nix-license = callPackage ./src/get_nix_license.nix { };
license-store-cache = buildPackage {
pname = "license-store-cache";
inherit src;
buildInputs = optionals stdenv.isDarwin [
libiconv
];
doCheck = false;
doNotRemoveReferencesToVendorDir = true;
cargoArtifacts = null;
cargoExtraArgs = "-p license-store-cache";
CARGO_PROFILE = "";
postInstall = ''
cache=$(mktemp)
$out/bin/license-store-cache $cache ${spdx-license-list-data.json}/json/details
rm -rf $out
mv $cache $out
'';
};
args = {
inherit src;
nativeBuildInputs = [
curl
installShellFiles
pkg-config
];
buildInputs = [
bzip2
curl
libgit2
openssl
zlib
zstd
] ++ optionals stdenv.isDarwin [
darwin.apple_sdk.frameworks.Security
] ++ optionals (stdenv.isDarwin && stdenv.isx86_64) [
darwin.apple_sdk.frameworks.CoreFoundation
];
cargoArtifacts = buildDepsOnly args;
cargoExtraArgs = "--no-default-features";
doInstallCargoArtifacts = false;
postPatch = ''
mkdir -p data
ln -s ${get-nix-license} data/get_nix_license.rs
ln -s ${license-store-cache} data/license-store-cache.zstd
'';
env = {
GEN_ARTIFACTS = "artifacts";
NIX = getExe nix;
NURL = getExe nurl;
ZSTD_SYS_USE_PKG_CONFIG = true;
};
meta = {
license = licenses.mpl20;
maintainers = with maintainers; [ figsoda ];
};
};
in
{
checks = {
build = self'.packages.default;
clippy = cargoClippy (args // {
cargoClippyExtraArgs = "-- -D warnings";
});
fmt = cargoFmt (removeAttrs args [ "cargoExtraArgs" ]);
test =
let
fixtures = src + "/src/lang/rust/fixtures";
lock = src + "/Cargo.lock";
getPackages = flip pipe [
importTOML
(getAttr "package")
(map ({ name, version, ... }@pkg:
nameValuePair "${name}-${version}" pkg))
listToAttrs
];
in
cargoNextest (args // {
cargoArtifacts = null;
cargoLockParsed = importTOML lock // {
package = attrValues (getPackages lock // concatMapAttrs
(name: _: optionalAttrs
(hasSuffix "-lock.toml" name)
(getPackages (fixtures + "/${name}")))
(readDir fixtures));
};
});
};
devShells.default = mkShell {
NIX_INIT_LOG = "nix_init=trace";
RUST_BACKTRACE = true;
shellHook = ''
mkdir -p data
ln -sf ${get-nix-license} data/get_nix_license.rs
ln -sf ${license-store-cache} data/license-store-cache.zstd
'';
};
formatter = nixpkgs-fmt;
packages.default = buildPackage (args // {
doCheck = false;
postInstall = ''
installManPage artifacts/nix-init.1
installShellCompletion artifacts/nix-init.{bash,fish} --zsh artifacts/_nix-init
'';
});
};
};
}