for (invtrait, invdir) in
    [(HasLeftInvariantMetric, LeftAction), (HasRightInvariantMetric, RightAction)],
    basis_type in [DefaultOrthonormalBasis, DefaultOrthogonalBasis]

    eval(
        quote
            function get_coordinates(
                ::TraitList{$invtrait},
                M::AbstractDecoratorManifold,
                p,
                X,
                B::$basis_type,
            )
                Xₑ = inverse_translate_diff(M, p, p, X, $invdir())
                return get_coordinates(M.manifold, p, Xₑ, B)
            end
            function get_coordinates!(
                ::TraitList{$invtrait},
                M::AbstractDecoratorManifold,
                c,
                p,
                X,
                B::$basis_type,
            )
                Xₑ = inverse_translate_diff(M, p, p, X, $invdir())
                return get_coordinates!(M.manifold, c, p, Xₑ, B)
            end

            function get_vector(
                ::TraitList{$invtrait},
                M::AbstractDecoratorManifold,
                p,
                c,
                B::$basis_type,
            )
                Xₑ = get_vector(M.manifold, p, c, B)
                return translate_diff(M, p, p, Xₑ, $invdir())
            end
            function get_vector!(
                ::TraitList{$invtrait},
                M::AbstractDecoratorManifold,
                X,
                p,
                c,
                B::$basis_type,
            )
                Xₑ = get_vector(M.manifold, p, c, B)
                return translate_diff!(M, X, p, p, Xₑ, $invdir())
            end
        end,
    )
end