Repository navigation
Expand file tree
/
Copy pathmd.oak
More file actions
676 lines (616 loc) · 15.6 KB
/
Copy pathmd.oak
File metadata and controls
676 lines (616 loc) · 15.6 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
// libmd implements a Markdown parser and renderer
{
slice: slice
map: map
each: each
take: take
filter: filter
reduce: reduce
every: every
append: append
} := import('std')
{
digit?: digit?
letter?: letter?
space?: space?
word?: word?
lower: lower
indexOf: indexOf
startsWith?: startsWith?
endsWith?: endsWith?
trimStart: trimStart
replace: replace
join: join
split: split
} := import('str')
{
format: format
} := import('fmt')
{
percentDecode: percentDecode
} := import('http')
// Type-generic Reader over an Oak iterable interface, i.e. strings and lists.
// This Reader is generic so that we can read through either a string (a list
// of chars) or a list of strings.
fn Reader(s) {
i := 0
fn peek s.(i)
fn last s.(i + 1)
fn back if i {
0 -> 0
_ -> i <- i - 1
}
fn next if i {
len(s) -> ?
_ -> {
c := s.(i)
i <- i + 1
c
}
}
fn expect?(prefix) if s |> slice(i) |> startsWith?(prefix) {
true -> {
i <- i + len(prefix)
true
}
_ -> false
}
fn itemIndex(list, it) {
fn sub(i) if i < len(list) {
true -> if list.(i) {
it -> i
_ -> sub(i + 1)
}
_ -> -1
}
sub(0)
}
fn readUntil(c) if index := s |> slice(i) |> itemIndex(c) {
-1 -> ?
_ -> {
substr := s |> slice(i, i + index)
i <- i + index
substr
}
}
fn readUntilPrefix(prefix) {
fn sub(index) if index + len(prefix) <= len(s) -> {
if part := s |> slice(index, index + len(prefix)) {
prefix -> {
substr := s |> slice(i, index)
i <- index
substr
}
_ -> sub(i + 1)
}
}
sub(i)
}
fn readUntilEnd {
substr := s |> slice(i)
i <- len(s)
substr
}
// readUntilMatchingDelim is a helper specifically for parsing delimited
// expressions like text in [] or (), that will attempt to read until a
// matching delimiter and return that read if the match exists, and return
// () if no match exists. This fn accounts for nested delimiters and
// ignores matching pairs within the delimited text expression.
fn readUntilMatchingDelim(left) {
right := if left {
// currently only supports [] and () (for Markdown links)
'[' -> ']'
'(' -> ')'
}
fn sub(index, stack) if stack {
0 -> index - 1
_ -> if c := s.(index) {
? -> -1
left -> sub(index + 1, stack + 1)
right -> sub(index + 1, stack - 1)
_ -> sub(index + 1, stack)
}
}
if matchingDelimIdx := sub(i, 1) {
-1 -> ?
_ -> {
substr := s |> slice(i, matchingDelimIdx)
i <- matchingDelimIdx
substr
}
}
}
{
peek: peek
last: last
back: back
next: next
expect?: expect?
readUntil: readUntil
readUntilPrefix: readUntilPrefix
readUntilEnd: readUntilEnd
readUntilMatchingDelim: readUntilMatchingDelim
}
}
// uword? reports whether a given character is a "word character", i.e. whether
// it is a part of a normal word. It intends to be UTF8 Unicode-aware and is
// used for text token disambiguation.
fn uword?(c) if word?(c) {
true -> true
_ -> codepoint(c) > 127
}
// tokenizeText tokenizes a paragraph or paragraph-like Markdown text (like
// headers) into a token stream
//
// This function encapsulates all disambiguation rules for e.g. parens inside A
// (link) tag parens, underscores inside words, and escaped special characters
// with backslashes.
fn tokenizeText(line) {
reader := Reader(line)
peek := reader.peek
next := reader.next
tokens := ['']
fn push(tok) tokens << tok << ''
fn append(suffix) tokens.(len(tokens) - 1) << suffix
fn sub if c := next() {
? -> ?
// italics & bold
'_', '*' -> {
if peek() {
c -> {
next()
push(c + c)
}
_ -> push(c)
}
sub()
}
// \ escapes any character
'\\' -> if d := next() {
? -> ?
_ -> sub(append(d))
}
// code snippet
'`'
// strikethrough
'~'
// image
'!', '[', ']', '(', ')' -> sub(push(c))
_ -> sub(append(c))
}
sub()
tokens |> with filter() fn(tok) tok != ''
}
// unifyTextNodes normalizes a Markdown AST so that runs of consecutive plain
// text nodes (strings) are combined into single plain text nodes.
fn unifyTextNodes(nodes, joiner) nodes |> with reduce([]) fn(acc, child) if type(child) {
:string -> if type(acc.(len(acc) - 1)) {
:string -> {
acc.(len(acc) - 1) << joiner << child
acc
}
_ -> acc << child
}
_ -> acc << if child.children {
? -> child
_ -> child.children := unifyTextNodes(child.children, joiner)
}
}
// parseText takes a stream of inline tokens from a header or paragraph section
// of a Markdown document and produces a list of inline AST nodes to be
// included in a Node.H or Node.P.
fn parseText(tokens) {
reader := Reader(tokens)
peek := reader.peek
next := reader.next
readUntil := reader.readUntil
readUntilMatchingDelim := reader.readUntilMatchingDelim
fn handleDelimitedRange(tok, tag, nodes, sub) if range := readUntil(tok) {
? -> sub(nodes << tok)
_ -> {
next() // eat trailing tok
sub(nodes << {
tag: tag
children: parseText(range)
})
}
}
fn sub(nodes) if tok := next() {
? -> nodes
'_' -> handleDelimitedRange('_', :em, nodes, sub)
'__' -> handleDelimitedRange('__', :strong, nodes, sub)
'*' -> handleDelimitedRange('*', :em, nodes, sub)
'**' -> handleDelimitedRange('**', :strong, nodes, sub)
'`' -> handleDelimitedRange('`', :code, nodes, sub)
'~' -> handleDelimitedRange('~', :strike, nodes, sub)
'[' -> if range := readUntilMatchingDelim('[') {
? -> sub(nodes << tok)
['x'] -> {
next() // eat matching ]
sub(nodes << {
tag: :checkbox
checked: true
})
}
[' '] -> {
next() // eat matching ]
sub(nodes << {
tag: :checkbox
checked: false
})
}
// eat matching ], then (
_ -> if c := (next(), next()) {
'(' -> if urlRange := readUntilMatchingDelim(c) {
? -> sub(nodes << tok + join(range) + ']' + c)
_ -> {
next() // swallow matching )
sub(nodes << {
tag: :a
href: join(urlRange)
children: parseText(range)
})
}
}
? -> sub(nodes << tok + join(range) + ']')
_ -> sub(nodes << tok + join(range) + ']' + c)
}
}
'!' -> if peek() {
'[' -> if range := (next(), readUntilMatchingDelim('[')) {
? -> sub(nodes << tok + '[')
['x'] -> {
next() // eat matching ]
sub(nodes << tok << {
tag: :checkbox
checked: true
})
}
[' '] -> {
next() // eat matching ]
sub(nodes << tok << {
tag: :checkbox
checked: false
})
}
// eat matching ], then (
_ -> if c := (next(), next()) {
'(' -> if urlRange := readUntilMatchingDelim(c) {
? -> sub(nodes << tok + '[' + join(range) + ']' + c)
_ -> {
next() // swallow matching )
sub(nodes << {
tag: :img
alt: join(range)
src: join(urlRange)
})
}
}
? -> sub(nodes << tok + '[' + join(range) + ']')
_ -> sub(nodes << tok + '[' + join(range) + ']' + c)
}
}
_ -> sub(nodes << tok)
}
_ -> sub(nodes << tok)
}
sub([]) |> unifyTextNodes('')
}
fn uListItemLine?(line) if line {
? -> false
_ -> line |> trimStart() |> startsWith?('- ')
}
fn oListItemLine?(line) if line {
? -> false
_ -> {
trimmedStart := line |> trimStart()
if dotIdx := trimmedStart |> indexOf('. ') {
-1, 0 -> false
_ -> trimmedStart |> slice(0, dotIdx) |> split() |> every(digit?)
}
}
}
fn listItemLine?(line) uListItemLine?(line) | oListItemLine?(line)
fn trimUListGetLevel(reader) {
level := len(reader.readUntil('-'))
reader.next() // '-'
reader.next() // ' '
level
}
fn trimOListGetLevel(reader) {
peek := reader.peek
next := reader.next
// read while whitespace
fn sub(i) if space?(peek()) {
true -> {
next()
sub(i + 1)
}
_ -> i
}
level := sub(0)
// eat until dot
reader.readUntil('.')
next() // eat the .
// if space after dot, swallow it
if peek() {
' ' -> next()
}
level
}
// lineNodeType reports the node type of a particular Markdown line for parsing
fn lineNodeType(line) if {
line = ? -> ?
line = '' -> :empty
startsWith?(line, '# ') -> :h1
startsWith?(line, '## ') -> :h2
startsWith?(line, '### ') -> :h3
startsWith?(line, '#### ') -> :h4
startsWith?(line, '##### ') -> :h5
startsWith?(line, '###### ') -> :h6
startsWith?(line, '>') -> :blockquote
startsWith?(line, '```') -> :pre
startsWith?(line, '---'), startsWith?(line, '***') -> :hr
startsWith?(line, '!html') -> :rawHTML
uListItemLine?(line) -> :ul
oListItemLine?(line) -> :ol
_ -> :p
}
// parse parses a byte string of Markdown formatted text into a Markdown AST,
// by looking at each line and either changing internal state if the line is a
// special line like a code fence or a raw HTML literal, or calling
// tokenizeText() if the line is a raw paragraph or header.
fn parse(text) text |> split('\n') |> Reader() |> parseDoc()
// parseDoc parses a Markdown docment from a line Reader. This allows
// sub-sections of the document to re-use this document parser to parse e.g.
// quoted sections that should be parsed as an independent subsection by
// providing a line Reader interface.
fn parseDoc(lineReader) {
fn sub(doc) if nodeType := lineNodeType(lineReader.peek()) {
:h1, :h2, :h3, :h4, :h5, :h6 -> sub(doc << parseHeader(nodeType, lineReader))
:blockquote -> sub(doc << parseBlockQuote(lineReader))
:pre -> sub(doc << parseCodeBlock(lineReader))
:ul, :ol -> sub(doc << parseList(lineReader, nodeType))
:rawHTML -> sub(doc << parseRawHTML(lineReader))
:p -> sub(doc << parseParagraph(lineReader))
:hr -> {
lineReader.next()
sub(doc << { tag: :hr })
}
:empty -> {
lineReader.next()
sub(doc)
}
_ -> doc
}
sub([])
}
fn parseHeader(nodeType, lineReader) {
reader := Reader(lineReader.next())
reader.readUntil(' ')
reader.next()
text := reader.readUntilEnd()
{
tag: nodeType
children: tokenizeText(text) |> parseText()
}
}
fn parseBlockQuote(lineReader) {
peek := lineReader.peek
next := lineReader.next
// A piece of a document inside a quoted block needs to be parsed as if it
// were its own document. The BlockQuotedLineReader provides a line Reader
// that masquerades as a document reader to parseDoc.
fn BlockQuoteLineReader(lineReader) {
fn returnIfQuoted(line) if lineNodeType(line) {
:blockquote -> line |> slice(1)
_ -> ?
}
fn peek returnIfQuoted(lineReader.peek())
fn last returnIfQuoted(lineReader.last())
fn back lineReader.back()
fn next if lineNodeType(lineReader.peek()) {
:blockquote -> lineReader.next() |> trimStart('>')
_ -> ?
}
fn expect? ? // NOTE: not implemented
fn readUntil(c) lineReader.readdUntil('>' << c) |>
with map() fn(line) line |> slice(1)
fn readUntilPrefix(prefix) lineReader.readUntilPrefix('>' << c) |>
with map() fn(line) line |> slice(1)
fn readUntilMatchingDelim ? // NOTE: not implemented
{
peek: peek
last: last
back: back
next: next
expect?: expect?
readUntil: readUntil
readUntilPrefix: readUntilPrefix
readUntilEnd: lineReader.readUntilEnd
readUntilMatchingDelim: readUntilMatchingDelim
}
}
{
tag: :blockquote
children: BlockQuoteLineReader(lineReader) |> parseDoc()
}
}
fn parseCodeBlock(lineReader) {
peek := lineReader.peek
next := lineReader.next
startTag := next() // eat starting pre tag
lang := if rest := startTag |> slice(3) {
'' -> ''
_ -> rest
}
fn sub(lines) if lineNodeType(peek()) {
:pre, ? -> lines
_ -> sub(lines << next())
}
children := sub([])
next() // eat ending pre tag
{
tag: :pre
children: [{
tag: :code
lang: lang
children: unifyTextNodes(children, '\n')
}]
}
}
fn parseRawHTML(lineReader) {
peek := lineReader.peek
next := lineReader.next
startMarkLine := next()
firstLine := startMarkLine |> slice(len('!html '))
fn sub(lines) if lineNodeType(peek()) {
:empty, ? -> lines
_ -> sub(lines << next())
}
children := sub([firstLine])
{
tag: :rawHTML
children: unifyTextNodes(children, '\n')
}
}
fn parseList(lineReader, listType) {
peek := lineReader.peek
next := lineReader.next
fn sub(items) if listItemLine?(peek()) {
false -> items
_ -> {
// TODO: provide a way for one listItem to contain 2+ paragraphs
// The current convention seems to be that if there is at least one
// multi-paragraph listItem in a UL, every listItem in the UL gets
// <p>s rather than inline text nodes as content.
line := next()
lineType := lineNodeType(line)
reader := Reader(line)
trimmer := if lineType {
:ul -> trimUListGetLevel
:ol -> trimOListGetLevel
}
level := trimmer(reader)
text := reader.readUntilEnd()
listItem := {
tag: :li
level: level
children: tokenizeText(text) |> parseText()
}
// handle list items that have distinct levels
if lastItem := items.(len(items) - 1) {
? -> sub(items << listItem)
_ -> if {
lastItem.level = level -> if lineType {
// continue if same list type; otherwise re-parse
listType -> sub(items << listItem)
_ -> {
lineReader.back()
items
}
}
lastItem.level < level -> {
// indent in: begin parsing a separate list
lineReader.back()
list := parseList(lineReader, lineType)
lastItem.children << list
sub(items)
}
_ -> {
// indent out: give up control in this parsing depth
lineReader.back()
items
}
}
}
}
}
children := sub([])
// remove the level annotations
children |> each(fn(child) if child.tag = :li -> child.level := _)
{
tag: listType
children: children
}
}
fn parseParagraph(lineReader) {
peek := lineReader.peek
next := lineReader.next
fn sub(lines) if lineNodeType(peek()) {
:p -> {
text := next()
if [text |> endsWith?(' '), text.(len(text) - 1)] {
[true, _] -> {
lines |> append(text |> take(len(text) - 2) |>
tokenizeText() |> parseText())
sub(lines << { tag: :br })
}
[_, '\\'] -> {
lines |> append(text |> take(len(text) - 1) |>
tokenizeText() |> parseText())
sub(lines << { tag: :br })
}
_ -> sub(lines |> append(tokenizeText(text) |> parseText()))
}
}
_ -> lines
}
{
tag: :p
children: sub([]) |> unifyTextNodes(' ')
}
}
// compile transforms a Markdown AST node to HTML
fn compile(nodes) nodes |> map(compileNode) |> join()
fn wrap(tag, node) '<' << tag << '>' << compile(node.children) << '</' << tag << '>'
fn sanitizeAttr(attr) {
attr |> map(fn(c) if c {
'<' -> '<'
'\'' -> '''
'"' -> '"'
_ -> c
})
}
fn sanitizeURL(url) {
encodedURL := url |> percentDecode() |> map(fn(c) if {
word?(c), c = '/', c = ':' -> c
_ -> ''
}) |> lower()
if {
encodedURL |> startsWith?('javascript:')
encodedURL |> startsWith?('data:') -> ''
_ -> sanitizeAttr(url)
}
}
// compileNode transforms an individual Markdown AST node into HTML
fn compileNode(node) if type(node) {
:string -> node |> map(fn(c) if c {
'&' -> '&'
'<' -> '<'
_ -> c
})
_ -> if node.tag {
:p, :em, :strong, :strike
:h1, :h2, :h3, :h4, :h5, :h6
:pre, :ul, :ol, :li, :blockquote -> wrap(node.tag |> string(), node)
:a -> '<a href="{{0}}">{{1}}</a>' |> format(sanitizeURL(node.href), compile(node.children))
:img -> '<img alt="{{0}}" src="{{1}}"/>' |> format(sanitizeAttr(node.alt), sanitizeURL(node.src))
:code -> if node.lang {
'', ? -> wrap('code', node)
_ -> '<code data-lang="{{0}}">{{1}}</code>' |>
format(sanitizeAttr(node.lang), compile(node.children))
}
:checkbox -> '<input type="checkbox" ' << if node.checked {
true -> 'checked'
_ -> ''
} << '/>'
:br -> '<br/>'
:hr -> '<hr/>'
:rawHTML -> node.children.0
_ -> '<span style="color:red">Unknown Markdown node {{0}}</span>' |> format(string(node) |> compileNode())
}
}
// transform wraps the Markdown parser and compiler into a single function to be
// invoked by the library consumer.
fn transform(text) text |> parse() |> compile()